FUNCTION "FC2027_ZC_FF_SEC" : Void
TITLE = FC2027_ZC_FF_SEC
{ S7_Optimized_Access := 'TRUE' }
AUTHOR : ABH
FAMILY : ZeusControl
VERSION : 1.0
//Funcion para gestion de Flip Flop secuencial
   VAR_INPUT 
      Pulso1Seg : Bool;   // Pulso 1 segundo
   END_VAR

   VAR_TEMP 
      for_i : Int;
      t_N_MAX : Int;
      for_j : Int;
      t_SumaFlip : Int;
   END_VAR

   VAR CONSTANT 
      REPOSO : SInt := 0;
      FLOP : SInt := 10;
      FLIP : SInt := 20;
   END_VAR


BEGIN
	REGION DESCRIPCION
	(*
	###### (C)Copyright ZeusControl 2023 - 2025
	
	---
	### Información del Sistema
	| Hardware Compatible | Entorno de Ingeniería |
	|---------------------|-----------------------|
	| PLC serie 1200/1500 | TIA Portal 18         |
	
	---
	> **Restricciones:** Ninguna.
	
	---
	### Descripción Funcional
	
	Función encargada de gestionar un dispositivo flip flop secuencial.
	
	Las tareas que realiza son las siguientes:
	
	- Gestionar la activacion y calculos de tiempo de cambio entre ordenes Flip y Flop.
	- Adicionalmente, se gestiona tambien la posibilidad de pausar el contaje del tiempo, para evitar su reinicializacion en caso de pausa.
	
	---
	### Dependencias Requeridas
	| Tipo | Elementos |
	|------|-----------|
	| FC   | - |
	| FB   | - |
	| DB   | `DB2027_FF_SEC` |
	| UDT  | `UDT_ZC_DISP_FF_SEC` |
	    
	---
	### Historial de Cambios
	| Versión  | Fecha      | Técnico | Cambios |
	|----------|------------|---------|---------|
	| 00.00.01 | 02.10.2023 | (ABH)   | Primera version. |
	| 00.00.02 | 28.11.2023 | (ABH)   | Se añade condicion de activacion del Flip Flop a que algun SP sea mayor que 0. |
	| 01.00.00 | 15.10.2025 | (ABH)   | Se añade orden pausa para dejar de contar. Refactorizacion de logica de gestion de flips. |
	*)
	END_REGION DESCRIPCION
	
	
	REGION COMPROBACION_N_MAX
	    
	    //  Si no hay dispositivos declarados, salimos del bloque inmediatamente
	    IF "N_MAX_DISP_FF_SEC" <= 0 THEN
	        RETURN;
	    END_IF;
	    
	    //  Traspaso de N_MAX a variable temporal para evitar fallos de compilacion
	    #t_N_MAX := "N_MAX_DISP_FF_SEC";
	    
	END_REGION COMPROBACION_N_MAX
	
	
	//  ==========================================================================================================
	REGION GESTION_DISPOSITIVO
	    
	    FOR #for_i := 1 TO #t_N_MAX DO
	        
	        // ==========================================================================================================
	        REGION COMPROBACIONES_INICIALES
	            
	            //  Suma de seguridad por FOR (Determinista)
	            #t_SumaFlip := 0;
	            FOR #for_j := 1 TO 10 DO
	                #t_SumaFlip += "DB2027_FF_SEC".FF_SEC[#for_i].Config_SetPointTiempoFlip[#for_j];
	            END_FOR;
	            
	            // Si no hay orden o los tiempos globales son 0, reseteamos valores y salimos de la funcion
	            IF NOT "DB2027_FF_SEC".FF_SEC[#for_i].Orden_Activar OR (#t_SumaFlip <= 0 AND "DB2027_FF_SEC".FF_SEC[#for_i].Config_SetPointTiempoFlop <= 0) THEN
	                "DB2027_FF_SEC".FF_SEC[#for_i].Estado_SalidaFlop := FALSE;
	                FOR #for_j := 1 TO 10 DO
	                    "DB2027_FF_SEC".FF_SEC[#for_i].Estado_SalidaFlip[#for_j] := FALSE;
	                END_FOR;
	                
	                "DB2027_FF_SEC".FF_SEC[#for_i].Aux_Tiempo := 0;
	                "DB2027_FF_SEC".FF_SEC[#for_i].Estado_Etapa := #REPOSO;
	                "DB2027_FF_SEC".FF_SEC[#for_i].Aux_FlipActual := 0;
	                "DB2027_FF_SEC".FF_SEC[#for_i].Aux_Inicializacion := FALSE;
	                RETURN;
	            END_IF;
	            
	        END_REGION COMPROBACIONES_INICIALES
	        
	        
	        // ==========================================================================================================
	        REGION INICIALIZACION
	            
	            //  Arranque inicial forzado a Flop si no hay estado activo
	            IF NOT "DB2027_FF_SEC".FF_SEC[#for_i].Aux_Inicializacion THEN
	                "DB2027_FF_SEC".FF_SEC[#for_i].Estado_Etapa := #FLOP;
	                "DB2027_FF_SEC".FF_SEC[#for_i].Aux_FlipActual := 0;
	                "DB2027_FF_SEC".FF_SEC[#for_i].Aux_Inicializacion := TRUE;
	            END_IF;
	            
	        END_REGION INICIALIZACION
	        
	        
	        // ==========================================================================================================
	        REGION LOGICA_DE_ESTADOS        
	            
	            CASE "DB2027_FF_SEC".FF_SEC[#for_i].Estado_Etapa OF
	                    
	                #FLOP:
	                    //  Salidas
	                    "DB2027_FF_SEC".FF_SEC[#for_i].Estado_SalidaFlop := TRUE;
	                    FOR #for_j := 1 TO 10 DO
	                        "DB2027_FF_SEC".FF_SEC[#for_i].Estado_SalidaFlip[#for_j] := FALSE;
	                    END_FOR;
	                    
	                    //  Conteo de tiempo
	                    IF #Pulso1Seg AND NOT "DB2027_FF_SEC".FF_SEC[#for_i].Orden_Pausa THEN
	                        "DB2027_FF_SEC".FF_SEC[#for_i].Aux_Tiempo += 1;
	                    END_IF;
	                    
	                    //  Transición
	                    IF "DB2027_FF_SEC".FF_SEC[#for_i].Aux_Tiempo >= "DB2027_FF_SEC".FF_SEC[#for_i].Config_SetPointTiempoFlop THEN
	                        "DB2027_FF_SEC".FF_SEC[#for_i].Aux_Tiempo := 0;
	                        "DB2027_FF_SEC".FF_SEC[#for_i].Aux_FlipActual := 11; // Fallback por defecto
	                        
	                        //  Buscar primer Flip válido
	                        FOR #for_j := 1 TO 10 DO
	                            IF "DB2027_FF_SEC".FF_SEC[#for_i].Config_SetPointTiempoFlip[#for_j] > 0 THEN
	                                "DB2027_FF_SEC".FF_SEC[#for_i].Aux_FlipActual := #for_j;
	                                EXIT; // Corta el FOR en el primer acierto
	                            END_IF;
	                        END_FOR;
	                        
	                        //  Transición si encontró algo válido
	                        IF "DB2027_FF_SEC".FF_SEC[#for_i].Aux_FlipActual <= 10 THEN
	                            "DB2027_FF_SEC".FF_SEC[#for_i].Estado_Etapa := #FLIP;
	                        END_IF;
	                    END_IF;
	                    
	                #FLIP:
	                    //  Salidas
	                    "DB2027_FF_SEC".FF_SEC[#for_i].Estado_SalidaFlop := FALSE;
	                    FOR #for_j := 1 TO 10 DO
	                        IF #for_j = "DB2027_FF_SEC".FF_SEC[#for_i].Aux_FlipActual THEN
	                            "DB2027_FF_SEC".FF_SEC[#for_i].Estado_SalidaFlip[#for_j] := TRUE;
	                        ELSE
	                            "DB2027_FF_SEC".FF_SEC[#for_i].Estado_SalidaFlip[#for_j] := FALSE;
	                        END_IF;
	                    END_FOR;
	                    
	                    //  Conteo de tiempo
	                    IF #Pulso1Seg AND NOT "DB2027_FF_SEC".FF_SEC[#for_i].Orden_Pausa THEN
	                        "DB2027_FF_SEC".FF_SEC[#for_i].Aux_Tiempo += 1;
	                    END_IF;
	                    
	                    ///  Transición
	                    IF "DB2027_FF_SEC".FF_SEC[#for_i].Aux_Tiempo >= "DB2027_FF_SEC".FF_SEC[#for_i].Config_SetPointTiempoFlip["DB2027_FF_SEC".FF_SEC[#for_i].Aux_FlipActual] THEN
	                        "DB2027_FF_SEC".FF_SEC[#for_i].Aux_Tiempo := 0;
	                        "DB2027_FF_SEC".FF_SEC[#for_i].Aux_FlipActual += 1; // Apunta al siguiente
	                        
	                        // Búsqueda del siguiente Flip válido
	                        FOR #for_j := "DB2027_FF_SEC".FF_SEC[#for_i].Aux_FlipActual TO 10 DO
	                            IF "DB2027_FF_SEC".FF_SEC[#for_i].Config_SetPointTiempoFlip[#for_j] > 0 THEN
	                                "DB2027_FF_SEC".FF_SEC[#for_i].Aux_FlipActual := #for_j;
	                                EXIT;
	                            END_IF;
	                            // Si llega al final sin encontrar nada
	                            IF #for_j = 10 THEN
	                                "DB2027_FF_SEC".FF_SEC[#for_i].Aux_FlipActual := 11;
	                            END_IF;
	                        END_FOR;
	                        
	                        // Si rebasó el límite, vuelve al Flop
	                        IF "DB2027_FF_SEC".FF_SEC[#for_i].Aux_FlipActual > 10 THEN
	                            "DB2027_FF_SEC".FF_SEC[#for_i].Estado_Etapa := #FLOP;
	                        END_IF;
	                    END_IF;
	                    
	                ELSE
	                    "DB2027_FF_SEC".FF_SEC[#for_i].Estado_Etapa := #REPOSO;
	            END_CASE;
	            
	        END_REGION LOGICA_DE_ESTADOS 
	        
	    END_FOR;
	
	END_REGION GESTION_DISPOSITIVO
	  
END_FUNCTION

