{
    S7_Author := "ABH";
    S7_BlockComment := "MLC_4Wd";
    S7_BlockNumber := "2835";
    S7_BlockTitle := "MLC_3Dt";
    S7_EditorMode := "SCL";
    S7_Family := "ZeusControl";
    S7_Optimized := "TRUE";
    S7_Version := "1.0"
}
FUNCTION "FC2835_ZC_PID_MUX" : Void
    VAR_INPUT
        Arranque : Bool;
    END_VAR
    VAR_TEMP
        for_mux : Int;
        t_Index : Int;
        t_oldIndex : Int;
        t_N_MAX : Int;
        t_CambioDesdeHMI : Bool;
        t_CambioDesdeMux : Bool;
    END_VAR

    { S7_Language := "SCL" }
    NETWORK
        REGION DESCRIPCION
        (*
        ###### (C)Copyright ZeusControl 2020 - 2026
        
        ---
        ### Información del Sistema
        | Hardware Compatible | Entorno de Ingeniería |
        |---------------------|-----------------------|
        | PLC serie 1200/1500 | TIA Portal 18         |
        
        ---
        > **Restricciones:** Ninguna.
        
        - - -
        ### Descripción Funcional
        El bloque implementa la gestión de multiplexado estático para el dispositivo PID, exponiendo la matriz de equipos de la planta a los sistemas de supervisión SCADA Clásicos (WinCC Professional) sin necesidad de acceso indexado nativo.
        
        Funcionalidades principales de la arquitectura:
        - En el primer arranque del PLC (`#Arranque`), inicializa a `0` los índices (`Index` y `oldIndex`) de todos los canales de multiplexado.
        - Validación de los límites del índice de cada multiplexado frente a la constante `N_MAX_DISP_PID`.
        - Detección de cambio de índice (`Index <> oldIndex`) para cargar la estructura completa del equipo seleccionado (`DB2035_PID.PID[X]`) en la interfaz del multiplexor.
        - Transferencia continua de datos de Solo Lectura (estados, valores actuales, alarmas) desde el PLC hacia el SCADA.
        - Transferencia bidireccional segura de datos de Escritura (consignas, configuraciones y modos) evaluando máscaras de cambios (`CambioDesdeHMI` vs `CambioDesdeMux`) para evitar sobrescrituras accidentales.
        - Gestión de comandos (Resets, pulsadores) con auto-reseteo para evitar el efecto rebote.
        - Caso especial de índice `0`: carga la estructura `PID[0]` (reservada y vacía) para limpiar la pantalla del SCADA.
        
        > ** Restricciones: ** Exclusivo para SCADAs sin soporte de indexación directa.
        
        - - -
        ### Dependencias Requeridas
        | Tipo | Elementos |
        |------|-----------|
        | FC   | - |
        | FB   | - |
        | DB   | `DB2035_PID` |
        | UDT  | `ZC_DISP_PID`, `ZC_DISP_MUX_PID` | 
        ---
        ### Historial de Cambios
        | Versión  | Fecha      | Técnico | Cambios |
        |----------|------------|---------|---------|
        | 01.00.00 | 10.07.2026 | (ABH)   | Primera versión extraído a FC independiente. Refactorizacion de multiplexado para su uso solo en WinCC Professional.|
        *)
        END_REGION DESCRIPCION
        
        
        REGION COMPROBACION_N_MAX
            
            //  Si no hay Scada declarados, salimos del bloque inmediatamente
            IF "N_MAX_SCADA" <= 0 THEN
                RETURN;
            END_IF;
            
            //  Traspaso de N_MAX a variable temporal para evitar fallos de compilacion
            #t_N_MAX := "N_MAX_SCADA";
            
        END_REGION COMPROBACION_N_MAX
        
        
        REGION MULTIPLEXADO
            
            //  ===========================================================================================================
            //  Al arranque del PLC, ponemos a 0 todos los indices de los multiplexados
            IF #Arranque THEN
                FOR #for_mux := 1 TO #t_N_MAX DO
                    "DB2835_PID_MUX".Mux.Scada[#for_mux].Index :=
                    "DB2835_PID_MUX".Mux.Scada[#for_mux].oldIndex := 0;
                END_FOR;
            END_IF;
            
            //  ===========================================================================================================
            //  Gestion de multiplexado
            FOR #for_mux := 1 TO #t_N_MAX DO
                
                //  ===============================================================================================================
                //  Antes de iniciar la logica del multiplexado, revisamos los limites
                REGION LIMITES
                    
                    //  ===========================================================================================================
                    //  Limites
                    IF "DB2835_PID_MUX".Mux.Scada[#for_mux].Index < 0 THEN
                        "DB2835_PID_MUX".Mux.Scada[#for_mux].Index := 0;
                    END_IF;
                    IF "DB2835_PID_MUX".Mux.Scada[#for_mux].Index > "N_MAX_DISP_PID" THEN
                        "DB2835_PID_MUX".Mux.Scada[#for_mux].Index := "N_MAX_DISP_PID";
                    END_IF;
                    
                END_REGION LIMITES
                
                
                REGION INDICES
                    
                    //  Pasamos el indice a variable temporal para evisar cambios no deseados
                    #t_Index := "DB2835_PID_MUX".Mux.Scada[#for_mux].Index;
                    #t_oldIndex := "DB2835_PID_MUX".Mux.Scada[#for_mux].oldIndex;
                    
                END_REGION INDICES 
                
                
                
                
                IF "DB2835_PID_MUX".Mux.Scada[#for_mux].Habilitar THEN
                    
                    
                    //  ===========================================================================================================
                    //  Gestionamos solo los tipos 
                    IF #t_Index > 0 THEN
                        
                        REGION CARGA_INICIAL
                            
                            //  ===========================================================================================================
                            //  Al detectar un cambio en el indice del dispositivo, cargamos los valores del dispositivo que tenga el indice.
                            IF #t_Index <> #t_oldIndex THEN
                                
                                //  Traspaso de dispositivos al multiplexado
                                "DB2835_PID_MUX".Mux.Scada[#for_mux].PID := "DB2035_PID".PID[#t_Index];
                                "DB2835_PID_MUX".Mux.Scada[#for_mux].oldPID := "DB2035_PID".PID[#t_Index];
                                
                                //  ===========================================================================================================
                                //  Valor anterior del indice
                                "DB2835_PID_MUX".Mux.Scada[#for_mux].oldIndex := #t_Index;
                                
                            END_IF;
                            
                        END_REGION CARGA_INICIAL
                        
                        
                        REGION DATOS_LECTURA
                            
                            //  ===========================================================================================================
                            //  Movimiento de datos gestionados en FC
                            "DB2835_PID_MUX".Mux.Scada[#for_mux].PID.Estado_AutoMan := "DB2035_PID".PID[#t_Index].Estado_AutoMan;
                            "DB2835_PID_MUX".Mux.Scada[#for_mux].PID.Estado_ModeActivate := "DB2035_PID".PID[#t_Index].Estado_ModeActivate;
                            "DB2835_PID_MUX".Mux.Scada[#for_mux].PID.Estado_PV := "DB2035_PID".PID[#t_Index].Estado_PV;
                            "DB2835_PID_MUX".Mux.Scada[#for_mux].PID.Estado_ValorSalida := "DB2035_PID".PID[#t_Index].Estado_ValorSalida;
                            "DB2835_PID_MUX".Mux.Scada[#for_mux].PID.Estado_PV_0_100 := "DB2035_PID".PID[#t_Index].Estado_PV_0_100;
                            "DB2835_PID_MUX".Mux.Scada[#for_mux].PID.Estado_SP_0_100 := "DB2035_PID".PID[#t_Index].Estado_SP_0_100;
                            "DB2835_PID_MUX".Mux.Scada[#for_mux].PID.Estado_Error_SP_PV_0_100 := "DB2035_PID".PID[#t_Index].Estado_Error_SP_PV_0_100;
                            "DB2835_PID_MUX".Mux.Scada[#for_mux].PID.Estado_Mode := "DB2035_PID".PID[#t_Index].Estado_Mode;
                            "DB2835_PID_MUX".Mux.Scada[#for_mux].PID.Estado_EstadoPID := "DB2035_PID".PID[#t_Index].Estado_EstadoPID;
                            
                            "DB2835_PID_MUX".Mux.Scada[#for_mux].PID.Orden_ActivarAuto := "DB2035_PID".PID[#t_Index].Orden_ActivarAuto;
                            "DB2835_PID_MUX".Mux.Scada[#for_mux].PID.Orden_ConsignaAuto := "DB2035_PID".PID[#t_Index].Orden_ConsignaAuto;
                            
                            "DB2835_PID_MUX".Mux.Scada[#for_mux].PID.Alarmas_Error := "DB2035_PID".PID[#t_Index].Alarmas_Error;
                            "DB2835_PID_MUX".Mux.Scada[#for_mux].PID.Alarmas_ErrorBits := "DB2035_PID".PID[#t_Index].Alarmas_ErrorBits;
                            
                            "DB2835_PID_MUX".Mux.Scada[#for_mux].PID.Aux_oldForzar := "DB2035_PID".PID[#t_Index].Aux_oldForzar;
                            "DB2835_PID_MUX".Mux.Scada[#for_mux].PID.Aux_oldMode := "DB2035_PID".PID[#t_Index].Aux_oldMode;
                            "DB2835_PID_MUX".Mux.Scada[#for_mux].PID.Aux_SP_Manual := "DB2035_PID".PID[#t_Index].Aux_SP_Manual;
                            "DB2835_PID_MUX".Mux.Scada[#for_mux].PID.Aux_SP_Auto := "DB2035_PID".PID[#t_Index].Aux_SP_Auto;
                            "DB2835_PID_MUX".Mux.Scada[#for_mux].PID.Aux_oldGain := "DB2035_PID".PID[#t_Index].Aux_oldGain;
                            "DB2835_PID_MUX".Mux.Scada[#for_mux].PID.Aux_oldTi := "DB2035_PID".PID[#t_Index].Aux_oldTi;
                            "DB2835_PID_MUX".Mux.Scada[#for_mux].PID.Aux_oldTd := "DB2035_PID".PID[#t_Index].Aux_oldTd;
                            
                            
                            IF NOT "DB2835_PID_MUX".Mux.Scada[#for_mux].PID.Estado_AutoMan THEN
                                "DB2835_PID_MUX".Mux.Scada[#for_mux].PID.Orden_ConsignaForzado := "DB2035_PID".PID[#t_Index].Orden_ConsignaForzado;
                            END_IF;
                            
                            IF NOT "DB2835_PID_MUX".Mux.Scada[#for_mux].PID.Orden_ActivarAuto THEN
                                "DB2835_PID_MUX".Mux.Scada[#for_mux].PID.Orden_Forzar := FALSE;
                            END_IF;
                            
                        END_REGION DATOS_LECTURA
                        
                        
                        REGION DATOS_ESCRITURA
                            
                            REGION GESTION_CAMBIOS_DINAMICOS
                                
                                //  Estado Auto/Manual
                                IF "DB2035_PID".PID[#t_Index].Estado_AutoMan <> "DB2835_PID_MUX".Mux.Scada[#for_mux].oldPID.Estado_AutoMan THEN
                                    
                                    //  Cambio desde HMI
                                    "DB2835_PID_MUX".Mux.Scada[#for_mux].PID.Estado_AutoMan := "DB2035_PID".PID[#t_Index].Estado_AutoMan;
                                    "DB2835_PID_MUX".Mux.Scada[#for_mux].oldPID.Estado_AutoMan := "DB2035_PID".PID[#t_Index].Estado_AutoMan;
                                    
                                ELSIF "DB2835_PID_MUX".Mux.Scada[#for_mux].PID.Estado_AutoMan <> "DB2835_PID_MUX".Mux.Scada[#for_mux].oldPID.Estado_AutoMan THEN
                                    
                                    //  Cambio desde Multiplexado
                                    "DB2035_PID".PID[#t_Index].Estado_AutoMan := "DB2835_PID_MUX".Mux.Scada[#for_mux].PID.Estado_AutoMan;
                                    "DB2835_PID_MUX".Mux.Scada[#for_mux].oldPID.Estado_AutoMan := "DB2835_PID_MUX".Mux.Scada[#for_mux].PID.Estado_AutoMan;
                                    
                                END_IF;
                                
                                //  Orden Activar Manual
                                IF "DB2035_PID".PID[#t_Index].Orden_Forzar <> "DB2835_PID_MUX".Mux.Scada[#for_mux].oldPID.Orden_Forzar THEN
                                    
                                    //  Cambio desde HMI
                                    "DB2835_PID_MUX".Mux.Scada[#for_mux].PID.Orden_Forzar := "DB2035_PID".PID[#t_Index].Orden_Forzar;
                                    "DB2835_PID_MUX".Mux.Scada[#for_mux].oldPID.Orden_Forzar := "DB2035_PID".PID[#t_Index].Orden_Forzar;
                                    
                                ELSIF "DB2835_PID_MUX".Mux.Scada[#for_mux].PID.Orden_Forzar <> "DB2835_PID_MUX".Mux.Scada[#for_mux].oldPID.Orden_Forzar THEN
                                    
                                    //  Cambio desde Multiplexado
                                    "DB2035_PID".PID[#t_Index].Orden_Forzar := "DB2835_PID_MUX".Mux.Scada[#for_mux].PID.Orden_Forzar;
                                    "DB2835_PID_MUX".Mux.Scada[#for_mux].oldPID.Orden_Forzar := "DB2835_PID_MUX".Mux.Scada[#for_mux].PID.Orden_Forzar;
                                    
                                END_IF;
                                
                                //  Orden Consigna Manual
                                IF "DB2035_PID".PID[#t_Index].Orden_ConsignaForzado <> "DB2835_PID_MUX".Mux.Scada[#for_mux].oldPID.Orden_ConsignaForzado THEN
                                    
                                    //  Cambio desde HMI
                                    "DB2835_PID_MUX".Mux.Scada[#for_mux].PID.Orden_ConsignaForzado := "DB2035_PID".PID[#t_Index].Orden_ConsignaForzado;
                                    "DB2835_PID_MUX".Mux.Scada[#for_mux].oldPID.Orden_ConsignaForzado := "DB2035_PID".PID[#t_Index].Orden_ConsignaForzado;
                                    
                                ELSIF "DB2835_PID_MUX".Mux.Scada[#for_mux].PID.Orden_ConsignaForzado <> "DB2835_PID_MUX".Mux.Scada[#for_mux].oldPID.Orden_ConsignaForzado THEN
                                    
                                    //  Cambio desde Multiplexado
                                    "DB2035_PID".PID[#t_Index].Orden_ConsignaForzado := "DB2835_PID_MUX".Mux.Scada[#for_mux].PID.Orden_ConsignaForzado;
                                    "DB2835_PID_MUX".Mux.Scada[#for_mux].oldPID.Orden_ConsignaForzado := "DB2835_PID_MUX".Mux.Scada[#for_mux].PID.Orden_ConsignaForzado;
                                    
                                END_IF;
                                
                                //  Orden Ack
                                IF "DB2035_PID".PID[#t_Index].Orden_Ack <> "DB2835_PID_MUX".Mux.Scada[#for_mux].oldPID.Orden_Ack THEN
                                    
                                    //  Cambio desde HMI
                                    "DB2835_PID_MUX".Mux.Scada[#for_mux].PID.Orden_Ack := "DB2035_PID".PID[#t_Index].Orden_Ack;
                                    "DB2835_PID_MUX".Mux.Scada[#for_mux].oldPID.Orden_Ack := "DB2035_PID".PID[#t_Index].Orden_Ack;
                                    
                                ELSIF "DB2835_PID_MUX".Mux.Scada[#for_mux].PID.Orden_Ack <> "DB2835_PID_MUX".Mux.Scada[#for_mux].oldPID.Orden_Ack THEN
                                    
                                    //  Cambio desde Multiplexado
                                    "DB2035_PID".PID[#t_Index].Orden_Ack := "DB2835_PID_MUX".Mux.Scada[#for_mux].PID.Orden_Ack;
                                    "DB2835_PID_MUX".Mux.Scada[#for_mux].oldPID.Orden_Ack := "DB2835_PID_MUX".Mux.Scada[#for_mux].PID.Orden_Ack;
                                    
                                    "DB2835_PID_MUX".Mux.Scada[#for_mux].PID.Orden_Ack := FALSE;
                                    
                                END_IF;
                                
                                //  Orden Reset
                                IF "DB2035_PID".PID[#t_Index].Orden_Reset <> "DB2835_PID_MUX".Mux.Scada[#for_mux].oldPID.Orden_Reset THEN
                                    
                                    //  Cambio desde HMI
                                    "DB2835_PID_MUX".Mux.Scada[#for_mux].PID.Orden_Reset := "DB2035_PID".PID[#t_Index].Orden_Reset;
                                    "DB2835_PID_MUX".Mux.Scada[#for_mux].oldPID.Orden_Reset := "DB2035_PID".PID[#t_Index].Orden_Reset;
                                    
                                ELSIF "DB2835_PID_MUX".Mux.Scada[#for_mux].PID.Orden_Reset <> "DB2835_PID_MUX".Mux.Scada[#for_mux].oldPID.Orden_Reset THEN
                                    
                                    //  Cambio desde Multiplexado
                                    "DB2035_PID".PID[#t_Index].Orden_Reset := "DB2835_PID_MUX".Mux.Scada[#for_mux].PID.Orden_Reset;
                                    "DB2835_PID_MUX".Mux.Scada[#for_mux].oldPID.Orden_Reset := "DB2835_PID_MUX".Mux.Scada[#for_mux].PID.Orden_Reset;
                                    "DB2835_PID_MUX".Mux.Scada[#for_mux].PID.Orden_Reset := FALSE;
                                    
                                END_IF;
                                
                            END_REGION GESTION_CAMBIOS_DINAMICOS
                            
                            
                            REGION GESTION_CAMBIOS_CONFIG
                                
                                //  Marca auxiliar para indicar que el cambio es desde HMI
                                //  Comparamos el dispositivo original con el dispositivo real, para detectar cambios desde PLC o desde HMI
                                #t_CambioDesdeHMI :=
                                ("DB2835_PID_MUX".Mux.Scada[#for_mux].oldPID.Config_Gain<>"DB2035_PID".PID[#t_Index].Config_Gain)
                                OR ("DB2835_PID_MUX".Mux.Scada[#for_mux].oldPID.Config_Ti<>"DB2035_PID".PID[#t_Index].Config_Ti)
                                OR ("DB2835_PID_MUX".Mux.Scada[#for_mux].oldPID.Config_Td<>"DB2035_PID".PID[#t_Index].Config_Td)
                                OR ("DB2835_PID_MUX".Mux.Scada[#for_mux].oldPID.Config_LimiteSuperiorSalida<>"DB2035_PID".PID[#t_Index].Config_LimiteSuperiorSalida)
                                OR ("DB2835_PID_MUX".Mux.Scada[#for_mux].oldPID.Config_LimiteInferiorSalida<>"DB2035_PID".PID[#t_Index].Config_LimiteInferiorSalida);
                                
                                //  Marca auxiliar para indicar que el cambio es desde MUX SCADA
                                //  Comparamos el dispositivo original con el multiplexado, para detectar cambios desde multiplexado
                                #t_CambioDesdeMux :=
                                ("DB2835_PID_MUX".Mux.Scada[#for_mux].PID.Config_Gain<>"DB2835_PID_MUX".Mux.Scada[#for_mux].oldPID.Config_Gain)
                                OR ("DB2835_PID_MUX".Mux.Scada[#for_mux].PID.Config_Ti<>"DB2835_PID_MUX".Mux.Scada[#for_mux].oldPID.Config_Ti)
                                OR ("DB2835_PID_MUX".Mux.Scada[#for_mux].PID.Config_Td<>"DB2835_PID_MUX".Mux.Scada[#for_mux].oldPID.Config_Td)
                                OR ("DB2835_PID_MUX".Mux.Scada[#for_mux].PID.Config_LimiteSuperiorSalida<>"DB2835_PID_MUX".Mux.Scada[#for_mux].oldPID.Config_LimiteSuperiorSalida)
                                OR ("DB2835_PID_MUX".Mux.Scada[#for_mux].PID.Config_LimiteInferiorSalida<>"DB2835_PID_MUX".Mux.Scada[#for_mux].oldPID.Config_LimiteInferiorSalida);
                                
                            END_REGION GESTION_CAMBIOS_CONFIG
                            
                            
                            REGION TRASPASO_DATOS
                                
                                IF #t_CambioDesdeHMI THEN
                                    
                                    //  Al detectar un cambio desde el HMI, cargamos sus valores de nuevo al multiplexado
                                    "DB2835_PID_MUX".Mux.Scada[#for_mux].PID.Estado_AutoMan := "DB2035_PID".PID[#t_Index].Estado_AutoMan;
                                    "DB2835_PID_MUX".Mux.Scada[#for_mux].PID.Orden_Forzar := "DB2035_PID".PID[#t_Index].Orden_Forzar;
                                    "DB2835_PID_MUX".Mux.Scada[#for_mux].PID.Orden_ConsignaForzado := "DB2035_PID".PID[#t_Index].Orden_ConsignaForzado;
                                    "DB2835_PID_MUX".Mux.Scada[#for_mux].PID.Orden_Ack := "DB2035_PID".PID[#t_Index].Orden_Ack;
                                    "DB2835_PID_MUX".Mux.Scada[#for_mux].PID.Orden_Reset := "DB2035_PID".PID[#t_Index].Orden_Reset;
                                    
                                    "DB2835_PID_MUX".Mux.Scada[#for_mux].PID.Config_Gain := "DB2035_PID".PID[#t_Index].Config_Gain;
                                    "DB2835_PID_MUX".Mux.Scada[#for_mux].PID.Config_Ti := "DB2035_PID".PID[#t_Index].Config_Ti;
                                    "DB2835_PID_MUX".Mux.Scada[#for_mux].PID.Config_Td := "DB2035_PID".PID[#t_Index].Config_Td;
                                    "DB2835_PID_MUX".Mux.Scada[#for_mux].PID.Config_LimiteSuperiorSalida := "DB2035_PID".PID[#t_Index].Config_LimiteSuperiorSalida;
                                    "DB2835_PID_MUX".Mux.Scada[#for_mux].PID.Config_LimiteInferiorSalida := "DB2035_PID".PID[#t_Index].Config_LimiteInferiorSalida;
                                    
                                    //  Actualizamos el estado original para configuraciones
                                    "DB2835_PID_MUX".Mux.Scada[#for_mux].oldPID.Estado_AutoMan := "DB2035_PID".PID[#t_Index].Estado_AutoMan;
                                    "DB2835_PID_MUX".Mux.Scada[#for_mux].oldPID.Orden_Forzar := "DB2035_PID".PID[#t_Index].Orden_Forzar;
                                    "DB2835_PID_MUX".Mux.Scada[#for_mux].oldPID.Orden_ConsignaForzado := "DB2035_PID".PID[#t_Index].Orden_ConsignaForzado;
                                    "DB2835_PID_MUX".Mux.Scada[#for_mux].oldPID.Orden_Ack := "DB2035_PID".PID[#t_Index].Orden_Ack;
                                    "DB2835_PID_MUX".Mux.Scada[#for_mux].oldPID.Orden_Reset := "DB2035_PID".PID[#t_Index].Orden_Reset;
                                    
                                    "DB2835_PID_MUX".Mux.Scada[#for_mux].oldPID.Config_Gain := "DB2035_PID".PID[#t_Index].Config_Gain;
                                    "DB2835_PID_MUX".Mux.Scada[#for_mux].oldPID.Config_Ti := "DB2035_PID".PID[#t_Index].Config_Ti;
                                    "DB2835_PID_MUX".Mux.Scada[#for_mux].oldPID.Config_Td := "DB2035_PID".PID[#t_Index].Config_Td;
                                    "DB2835_PID_MUX".Mux.Scada[#for_mux].oldPID.Config_LimiteSuperiorSalida := "DB2035_PID".PID[#t_Index].Config_LimiteSuperiorSalida;
                                    "DB2835_PID_MUX".Mux.Scada[#for_mux].oldPID.Config_LimiteInferiorSalida := "DB2035_PID".PID[#t_Index].Config_LimiteInferiorSalida;
                                    
                                ELSIF #t_CambioDesdeMux THEN
                                    
                                    //  Al detectar un cambio desde el MUX, cargamos sus valores al dispositivo
                                    "DB2035_PID".PID[#t_Index].Estado_AutoMan := "DB2835_PID_MUX".Mux.Scada[#for_mux].PID.Estado_AutoMan;
                                    "DB2035_PID".PID[#t_Index].Orden_Forzar := "DB2835_PID_MUX".Mux.Scada[#for_mux].PID.Orden_Forzar;
                                    "DB2035_PID".PID[#t_Index].Orden_ConsignaForzado := "DB2835_PID_MUX".Mux.Scada[#for_mux].PID.Orden_ConsignaForzado;
                                    "DB2035_PID".PID[#t_Index].Orden_Ack := "DB2835_PID_MUX".Mux.Scada[#for_mux].PID.Orden_Ack;
                                    "DB2035_PID".PID[#t_Index].Orden_Reset := "DB2835_PID_MUX".Mux.Scada[#for_mux].PID.Orden_Reset;
                                    
                                    "DB2035_PID".PID[#t_Index].Config_Gain := "DB2835_PID_MUX".Mux.Scada[#for_mux].PID.Config_Gain;
                                    "DB2035_PID".PID[#t_Index].Config_Ti := "DB2835_PID_MUX".Mux.Scada[#for_mux].PID.Config_Ti;
                                    "DB2035_PID".PID[#t_Index].Config_Td := "DB2835_PID_MUX".Mux.Scada[#for_mux].PID.Config_Td;
                                    "DB2035_PID".PID[#t_Index].Config_LimiteSuperiorSalida := "DB2835_PID_MUX".Mux.Scada[#for_mux].PID.Config_LimiteSuperiorSalida;
                                    "DB2035_PID".PID[#t_Index].Config_LimiteInferiorSalida := "DB2835_PID_MUX".Mux.Scada[#for_mux].PID.Config_LimiteInferiorSalida;
                                    
                                    //  Actualizamos el estado original para configuraciones
                                    "DB2835_PID_MUX".Mux.Scada[#for_mux].oldPID.Estado_AutoMan := "DB2835_PID_MUX".Mux.Scada[#for_mux].PID.Estado_AutoMan;
                                    "DB2835_PID_MUX".Mux.Scada[#for_mux].oldPID.Orden_Forzar := "DB2835_PID_MUX".Mux.Scada[#for_mux].PID.Orden_Forzar;
                                    "DB2835_PID_MUX".Mux.Scada[#for_mux].oldPID.Orden_ConsignaForzado := "DB2835_PID_MUX".Mux.Scada[#for_mux].PID.Orden_ConsignaForzado;
                                    "DB2835_PID_MUX".Mux.Scada[#for_mux].oldPID.Orden_Ack := "DB2835_PID_MUX".Mux.Scada[#for_mux].PID.Orden_Ack;
                                    "DB2835_PID_MUX".Mux.Scada[#for_mux].oldPID.Orden_Reset := "DB2835_PID_MUX".Mux.Scada[#for_mux].PID.Orden_Reset;;
                                    
                                    "DB2835_PID_MUX".Mux.Scada[#for_mux].oldPID.Config_Gain := "DB2835_PID_MUX".Mux.Scada[#for_mux].PID.Config_Gain;
                                    "DB2835_PID_MUX".Mux.Scada[#for_mux].oldPID.Config_Ti := "DB2835_PID_MUX".Mux.Scada[#for_mux].PID.Config_Ti;
                                    "DB2835_PID_MUX".Mux.Scada[#for_mux].oldPID.Config_Td := "DB2835_PID_MUX".Mux.Scada[#for_mux].PID.Config_Td;
                                    "DB2835_PID_MUX".Mux.Scada[#for_mux].oldPID.Config_LimiteSuperiorSalida := "DB2835_PID_MUX".Mux.Scada[#for_mux].PID.Config_LimiteSuperiorSalida;
                                    "DB2835_PID_MUX".Mux.Scada[#for_mux].oldPID.Config_LimiteInferiorSalida := "DB2835_PID_MUX".Mux.Scada[#for_mux].PID.Config_LimiteInferiorSalida;
                                    
                                END_IF;
                                
                            END_REGION TRASPASO_DATOS
                            
                        END_REGION DATOS_ESCRITURA
                        
                    ELSE
                        
                        //  ===========================================================================================================
                        //  En caso de que el indice sea 0, movemos el valor de la PID[0] que no se usa para escribir el index.
                        "DB2835_PID_MUX".Mux.Scada[#for_mux].PID := "DB2035_PID".PID[0];
                        "DB2835_PID_MUX".Mux.Scada[#for_mux].oldPID := "DB2035_PID".PID[0];
                        
                        //  Actualizacion de estado anterior
                        "DB2835_PID_MUX".Mux.Scada[#for_mux].oldIndex := 0;
                        
                    END_IF;
                    
                ELSE
                    
                    //  Multiplexado no habilitado
                    "DB2835_PID_MUX".Mux.Scada[#for_mux].Index :=
                    "DB2835_PID_MUX".Mux.Scada[#for_mux].oldIndex := 0;
                    
                END_IF;
                
            END_FOR;
            
        END_REGION MULTIPLEXADO
        
        
    END_NETWORK
END_FUNCTION
