{
    S7_Author := "ABH";
    S7_BlockComment := "MLC_4xP";
    S7_BlockNumber := "2805";
    S7_BlockTitle := "MLC_3Pm";
    S7_EditorMode := "SCL";
    S7_Family := "ZeusControl";
    S7_Optimized := "TRUE";
    S7_Version := "1.0"
}
FUNCTION "FC2805_ZC_SD_MUX" : Void
    VAR_INPUT
        { S7_MLC := "MLC_3Tt" }
        Arranque : Bool;
    END_VAR
    VAR_TEMP
        for_mux : Int;
        t_Index : Int;
        t_oldIndex : Int;
        t_N_MAX : Int;
        t_CambioDesdeHMI : Bool;
        t_CambioDesdeMux : Bool;
    END_VAR

    { S7_Language := "SCL" }
    NETWORK
        REGION DESCRIPCION
        (*
        ###### (C)Copyright ZeusControl 2026 - 2026
        
        ---
        ### Información del Sistema
        | Hardware Compatible | Entorno de Ingeniería |
        |---------------------|-----------------------|
        | PLC serie 1200/1500 | TIA Portal 18         |
        
        ---
        > **Restricciones:** Ninguna.
        
        - - -
        ### Descripción Funcional
        El bloque implementa la gestión de multiplexado estático para el dispositivo salida digital, exponiendo la matriz de equipos de la planta a los sistemas de supervisión SCADA Clásicos (WinCC Professional) sin necesidad de acceso indexado nativo.
        
        Funcionalidades principales de la arquitectura:
        - En el primer arranque del PLC (`#Arranque`), inicializa a `0` los índices (`Index` y `oldIndex`) de todos los canales de multiplexado.
        - Validación de los límites del índice de cada multiplexado frente a la constante `N_MAX_DISP_SD`.
        - Detección de cambio de índice (`Index <> oldIndex`) para cargar la estructura completa del equipo seleccionado (`DB2005_SD.SD[X]`) en la interfaz del multiplexor.
        - Transferencia continua de datos de Solo Lectura (estados, valores actuales, alarmas) desde el PLC hacia el SCADA.
        - Transferencia bidireccional segura de datos de Escritura (consignas, configuraciones y modos) evaluando máscaras de cambios (`CambioDesdeHMI` vs `CambioDesdeMux`) para evitar sobrescrituras accidentales.
        - Gestión de comandos (Resets, pulsadores) con auto-reseteo para evitar el efecto rebote.
        - Caso especial de índice `0`: carga la estructura `SD[0]` (reservada y vacía) para limpiar la pantalla del SCADA.
        
        > ** Restricciones: ** Exclusivo para SCADAs sin soporte de indexación directa.
        
        - - -
        ### Dependencias Requeridas
        | Tipo | Elementos |
        |------|-----------|
        | FC   | - |
        | FB   | - |
        | DB   | `DB2005_SD` |
        | UDT  | `ZC_DISP_SD`, `ZC_DISP_MUX_SD` | 
        ---
        ### Historial de Cambios
        | Versión  | Fecha      | Técnico | Cambios |
        |----------|------------|---------|---------|
        | 01.00.00 | 10.07.2026 | (ABH)   | Primera versión extraído a FC independiente. Refactorizacion de multiplexado para su uso solo en WinCC Professional.|
        *)
        END_REGION DESCRIPCION
        
        
        REGION COMPROBACION_N_MAX
            
            //  Si no hay Scada declarados, salimos del bloque inmediatamente
            IF "N_MAX_SCADA" <= 0 THEN
                RETURN;
            END_IF;
            
            //  Traspaso de N_MAX a variable temporal para evitar fallos de compilacion
            #t_N_MAX := "N_MAX_SCADA";
            
        END_REGION COMPROBACION_N_MAX
        
        
        REGION MULTIPLEXADO
            
            //  ===========================================================================================================
            //  Al arranque del PLC, ponemos a 0 todos los indices de los multiplexados
            IF #Arranque THEN
                FOR #for_mux := 1 TO #t_N_MAX DO
                    "DB2805_SD_MUX".Mux.Scada[#for_mux].Index :=
                    "DB2805_SD_MUX".Mux.Scada[#for_mux].oldIndex := 0;
                END_FOR;
            END_IF;
            
            //  ===========================================================================================================
            //  Gestion de multiplexado
            FOR #for_mux := 1 TO #t_N_MAX DO
                
                //  ===============================================================================================================
                //  Antes de iniciar la logica del multiplexado, revisamos los limites
                REGION LIMITES
                    
                    //  ===========================================================================================================
                    //  Limites
                    IF "DB2805_SD_MUX".Mux.Scada[#for_mux].Index < 0 THEN
                        "DB2805_SD_MUX".Mux.Scada[#for_mux].Index := 0;
                    END_IF;
                    IF "DB2805_SD_MUX".Mux.Scada[#for_mux].Index > "N_MAX_DISP_SD" THEN
                        "DB2805_SD_MUX".Mux.Scada[#for_mux].Index := "N_MAX_DISP_SD";
                    END_IF;
                    
                END_REGION LIMITES
                
                
                //  Traspaso de limites a variable temporal para evitar cambios no deseados
                REGION INDICES
                    
                    #t_Index := "DB2805_SD_MUX".Mux.Scada[#for_mux].Index;
                    #t_oldIndex := "DB2805_SD_MUX".Mux.Scada[#for_mux].oldIndex;
                    
                END_REGION INDICES
                
                
                IF "DB2805_SD_MUX".Mux.Scada[#for_mux].Habilitar THEN
                    
                    //  ===========================================================================================================
                    //  Gestionamos solo los tipos 
                    IF #t_Index > 0 THEN
                        
                        REGION CARGA_INICIAL
                            
                            //  ===========================================================================================================
                            //  Al detectar un cambio en el indice del dispositivo, cargamos los valores del dispositivo que tenga el indice.
                            IF #t_Index <> #t_oldIndex THEN
                                
                                //  Traspaso de dispositivos al multiplexado
                                "DB2805_SD_MUX".Mux.Scada[#for_mux].SD := "DB2005_SD".SD[#t_Index];
                                "DB2805_SD_MUX".Mux.Scada[#for_mux].oldSD := "DB2005_SD".SD[#t_Index];
                                
                                //  ===========================================================================================================
                                //  Valor anterior del indice
                                "DB2805_SD_MUX".Mux.Scada[#for_mux].oldIndex := #t_Index;
                                
                            END_IF;
                            
                        END_REGION CARGA_INICIAL
                        
                        
                        REGION DATOS_LECTURA
                            
                            //  ===========================================================================================================
                            //  Movimiento de datos gestionados en FC
                            "DB2805_SD_MUX".Mux.Scada[#for_mux].SD.Hmi_Estado := "DB2005_SD".SD[#t_Index].Hmi_Estado;
                            IF NOT "DB2005_SD".SD[#t_Index].Estado_AutoMan THEN
                                "DB2805_SD_MUX".Mux.Scada[#for_mux].SD.Orden_ActivarManual := "DB2005_SD".SD["DB2805_SD_MUX".Mux.Scada[#for_mux].Index].Orden_ActivarManual;
                            END_IF;
                            "DB2805_SD_MUX".Mux.Scada[#for_mux].SD.Estado_Activado := "DB2005_SD".SD[#t_Index].Estado_Activado;
                            "DB2805_SD_MUX".Mux.Scada[#for_mux].SD.Estado_Enclavado := "DB2005_SD".SD[#t_Index].Estado_Enclavado;
                            "DB2805_SD_MUX".Mux.Scada[#for_mux].SD.Estado_Salida := "DB2005_SD".SD[#t_Index].Estado_Salida;
                            "DB2805_SD_MUX".Mux.Scada[#for_mux].SD.Estado_SeguridadOk := "DB2005_SD".SD[#t_Index].Estado_SeguridadOk;
                            "DB2805_SD_MUX".Mux.Scada[#for_mux].SD.Orden_ActivarAuto := "DB2005_SD".SD[#t_Index].Orden_ActivarAuto;
                            "DB2805_SD_MUX".Mux.Scada[#for_mux].SD.Tiempos_TiempoAct := "DB2005_SD".SD[#t_Index].Tiempos_TiempoAct;
                            "DB2805_SD_MUX".Mux.Scada[#for_mux].SD.Tiempos_TiempoDes := "DB2005_SD".SD[#t_Index].Tiempos_TiempoDes;
                            "DB2805_SD_MUX".Mux.Scada[#for_mux].SD.Aux_oldActivado := "DB2005_SD".SD[#t_Index].Aux_oldActivado;
                            "DB2805_SD_MUX".Mux.Scada[#for_mux].SD.Aux_oldAutoMan := "DB2005_SD".SD[#t_Index].Aux_oldAutoMan;
                            "DB2805_SD_MUX".Mux.Scada[#for_mux].SD.Config_GrupoAlarma := "DB2005_SD".SD[#t_Index].Config_GrupoAlarma;
                            
                        END_REGION DATOS_LECTURA
                        
                        
                        REGION DATOS_ESCRITURA
                            
                            REGION GESTION_CAMBIOS_DINAMICOS
                                
                                //  ===========================================================================================================
                                //  Estado Auto/Manual
                                IF "DB2005_SD".SD[#t_Index].Estado_AutoMan <> "DB2805_SD_MUX".Mux.Scada[#for_mux].oldSD.Estado_AutoMan THEN
                                    //  Cambio desde HMI
                                    "DB2805_SD_MUX".Mux.Scada[#for_mux].SD.Estado_AutoMan := "DB2005_SD".SD[#t_Index].Estado_AutoMan;
                                    "DB2805_SD_MUX".Mux.Scada[#for_mux].oldSD.Estado_AutoMan := "DB2005_SD".SD[#t_Index].Estado_AutoMan;
                                ELSIF "DB2805_SD_MUX".Mux.Scada[#for_mux].SD.Estado_AutoMan <> "DB2805_SD_MUX".Mux.Scada[#for_mux].oldSD.Estado_AutoMan THEN
                                    //  Cambio desde Multiplexado
                                    "DB2005_SD".SD[#t_Index].Estado_AutoMan := "DB2805_SD_MUX".Mux.Scada[#for_mux].SD.Estado_AutoMan;
                                    "DB2805_SD_MUX".Mux.Scada[#for_mux].oldSD.Estado_AutoMan := "DB2805_SD_MUX".Mux.Scada[#for_mux].SD.Estado_AutoMan;
                                END_IF;
                                
                                //  ===========================================================================================================
                                //  Orden Activar Manual
                                IF "DB2005_SD".SD[#t_Index].Orden_ActivarManual <> "DB2805_SD_MUX".Mux.Scada[#for_mux].oldSD.Orden_ActivarManual THEN
                                    //  Cambio desde HMI
                                    "DB2805_SD_MUX".Mux.Scada[#for_mux].SD.Orden_ActivarManual := "DB2005_SD".SD[#t_Index].Orden_ActivarManual;
                                    "DB2805_SD_MUX".Mux.Scada[#for_mux].oldSD.Orden_ActivarManual := "DB2005_SD".SD[#t_Index].Orden_ActivarManual;
                                ELSIF "DB2805_SD_MUX".Mux.Scada[#for_mux].SD.Orden_ActivarManual <> "DB2805_SD_MUX".Mux.Scada[#for_mux].oldSD.Orden_ActivarManual THEN
                                    //  Cambio desde Multiplexado
                                    "DB2005_SD".SD[#t_Index].Orden_ActivarManual := "DB2805_SD_MUX".Mux.Scada[#for_mux].SD.Orden_ActivarManual;
                                    "DB2805_SD_MUX".Mux.Scada[#for_mux].oldSD.Orden_ActivarManual := "DB2805_SD_MUX".Mux.Scada[#for_mux].SD.Orden_ActivarManual;
                                END_IF;
                                
                            END_REGION GESTION_CAMBIOS_DINAMICOS
                            
                            
                            REGION GESTION_CAMBIOS_CONFIG
                                
                                //  Marca auxiliar para indicar que el cambio es desde HMI
                                //  Comparamos el dispositivo original con el dispositivo real, para detectar cambios desde PLC o desde HMI
                                #t_CambioDesdeHMI :=
                                ("DB2805_SD_MUX".Mux.Scada[#for_mux].oldSD.Config_DireccionSalidaBit <> "DB2005_SD".SD[#t_Index].Config_DireccionSalidaBit)
                                OR ("DB2805_SD_MUX".Mux.Scada[#for_mux].oldSD.Config_DireccionSalidaByte <> "DB2005_SD".SD[#t_Index].Config_DireccionSalidaByte)
                                OR ("DB2805_SD_MUX".Mux.Scada[#for_mux].oldSD.Config_Habilitar <> "DB2005_SD".SD[#t_Index].Config_Habilitar)
                                OR ("DB2805_SD_MUX".Mux.Scada[#for_mux].oldSD.Config_HabilitarInvertir <> "DB2005_SD".SD[#t_Index].Config_HabilitarInvertir)
                                OR ("DB2805_SD_MUX".Mux.Scada[#for_mux].oldSD.Config_HabilitarRetardoAct <> "DB2005_SD".SD[#t_Index].Config_HabilitarRetardoAct)
                                OR ("DB2805_SD_MUX".Mux.Scada[#for_mux].oldSD.Config_HabilitarRetardoDes <> "DB2005_SD".SD[#t_Index].Config_HabilitarRetardoDes)
                                OR ("DB2805_SD_MUX".Mux.Scada[#for_mux].oldSD.Config_TipoAcceso <> "DB2005_SD".SD[#t_Index].Config_TipoAcceso)
                                OR ("DB2805_SD_MUX".Mux.Scada[#for_mux].oldSD.Tiempos_SetPointTiempoAct <> "DB2005_SD".SD[#t_Index].Tiempos_SetPointTiempoAct)
                                OR ("DB2805_SD_MUX".Mux.Scada[#for_mux].oldSD.Tiempos_SetPointTiempoDes <> "DB2005_SD".SD[#t_Index].Tiempos_SetPointTiempoDes);
                                
                                //  Marca auxiliar para indicar que el cambio es desde MUX SCADA
                                //  Comparamos el dispositivo original con el multiplexado, para detectar cambios desde multiplexado
                                #t_CambioDesdeMux :=
                                ("DB2805_SD_MUX".Mux.Scada[#for_mux].SD.Config_DireccionSalidaBit <> "DB2805_SD_MUX".Mux.Scada[#for_mux].oldSD.Config_DireccionSalidaBit)
                                OR ("DB2805_SD_MUX".Mux.Scada[#for_mux].SD.Config_DireccionSalidaByte <> "DB2805_SD_MUX".Mux.Scada[#for_mux].oldSD.Config_DireccionSalidaByte)
                                OR ("DB2805_SD_MUX".Mux.Scada[#for_mux].SD.Config_Habilitar <> "DB2805_SD_MUX".Mux.Scada[#for_mux].oldSD.Config_Habilitar)
                                OR ("DB2805_SD_MUX".Mux.Scada[#for_mux].SD.Config_HabilitarInvertir <> "DB2805_SD_MUX".Mux.Scada[#for_mux].oldSD.Config_HabilitarInvertir)
                                OR ("DB2805_SD_MUX".Mux.Scada[#for_mux].SD.Config_HabilitarRetardoAct <> "DB2805_SD_MUX".Mux.Scada[#for_mux].oldSD.Config_HabilitarRetardoAct)
                                OR ("DB2805_SD_MUX".Mux.Scada[#for_mux].SD.Config_HabilitarRetardoDes <> "DB2805_SD_MUX".Mux.Scada[#for_mux].oldSD.Config_HabilitarRetardoDes)
                                OR ("DB2805_SD_MUX".Mux.Scada[#for_mux].SD.Config_TipoAcceso <> "DB2805_SD_MUX".Mux.Scada[#for_mux].oldSD.Config_TipoAcceso)
                                OR ("DB2805_SD_MUX".Mux.Scada[#for_mux].SD.Tiempos_SetPointTiempoAct <> "DB2805_SD_MUX".Mux.Scada[#for_mux].oldSD.Tiempos_SetPointTiempoAct)
                                OR ("DB2805_SD_MUX".Mux.Scada[#for_mux].SD.Tiempos_SetPointTiempoDes <> "DB2805_SD_MUX".Mux.Scada[#for_mux].oldSD.Tiempos_SetPointTiempoDes);
                                
                            END_REGION GESTION_CAMBIOS_CONFIG                    
                            
                            
                            REGION TRASPASO_DATOS
                                
                                IF #t_CambioDesdeHMI THEN
                                    
                                    //  Al detectar un cambio desde el HMI, cargamos sus valores de nuevo al multiplexado
                                    "DB2805_SD_MUX".Mux.Scada[#for_mux].SD.Estado_AutoMan := "DB2005_SD".SD[#t_Index].Estado_AutoMan;
                                    "DB2805_SD_MUX".Mux.Scada[#for_mux].SD.Orden_ActivarManual := "DB2005_SD".SD[#t_Index].Orden_ActivarManual;
                                    
                                    "DB2805_SD_MUX".Mux.Scada[#for_mux].SD.Config_DireccionSalidaBit := "DB2005_SD".SD[#t_Index].Config_DireccionSalidaBit;
                                    "DB2805_SD_MUX".Mux.Scada[#for_mux].SD.Config_DireccionSalidaByte := "DB2005_SD".SD[#t_Index].Config_DireccionSalidaByte;
                                    "DB2805_SD_MUX".Mux.Scada[#for_mux].SD.Config_Habilitar := "DB2005_SD".SD[#t_Index].Config_Habilitar;
                                    "DB2805_SD_MUX".Mux.Scada[#for_mux].SD.Config_HabilitarInvertir := "DB2005_SD".SD[#t_Index].Config_HabilitarInvertir;
                                    "DB2805_SD_MUX".Mux.Scada[#for_mux].SD.Config_HabilitarRetardoAct := "DB2005_SD".SD[#t_Index].Config_HabilitarRetardoAct;
                                    "DB2805_SD_MUX".Mux.Scada[#for_mux].SD.Config_HabilitarRetardoDes := "DB2005_SD".SD[#t_Index].Config_HabilitarRetardoDes;
                                    "DB2805_SD_MUX".Mux.Scada[#for_mux].SD.Config_TipoAcceso := "DB2005_SD".SD[#t_Index].Config_TipoAcceso;
                                    "DB2805_SD_MUX".Mux.Scada[#for_mux].SD.Tiempos_SetPointTiempoAct := "DB2005_SD".SD[#t_Index].Tiempos_SetPointTiempoAct;
                                    "DB2805_SD_MUX".Mux.Scada[#for_mux].SD.Tiempos_SetPointTiempoDes := "DB2005_SD".SD[#t_Index].Tiempos_SetPointTiempoDes;
                                    
                                    //  Actualizamos el estado original para configuraciones
                                    "DB2805_SD_MUX".Mux.Scada[#for_mux].oldSD.Config_DireccionSalidaBit := "DB2005_SD".SD[#t_Index].Config_DireccionSalidaBit;
                                    "DB2805_SD_MUX".Mux.Scada[#for_mux].oldSD.Config_DireccionSalidaByte := "DB2005_SD".SD[#t_Index].Config_DireccionSalidaByte;
                                    "DB2805_SD_MUX".Mux.Scada[#for_mux].oldSD.Config_Habilitar := "DB2005_SD".SD[#t_Index].Config_Habilitar;
                                    "DB2805_SD_MUX".Mux.Scada[#for_mux].oldSD.Config_HabilitarInvertir := "DB2005_SD".SD[#t_Index].Config_HabilitarInvertir;
                                    "DB2805_SD_MUX".Mux.Scada[#for_mux].oldSD.Config_HabilitarRetardoAct := "DB2005_SD".SD[#t_Index].Config_HabilitarRetardoAct;
                                    "DB2805_SD_MUX".Mux.Scada[#for_mux].oldSD.Config_HabilitarRetardoDes := "DB2005_SD".SD[#t_Index].Config_HabilitarRetardoDes;
                                    "DB2805_SD_MUX".Mux.Scada[#for_mux].oldSD.Config_TipoAcceso := "DB2005_SD".SD[#t_Index].Config_TipoAcceso;
                                    "DB2805_SD_MUX".Mux.Scada[#for_mux].oldSD.Tiempos_SetPointTiempoAct := "DB2005_SD".SD[#t_Index].Tiempos_SetPointTiempoAct;
                                    "DB2805_SD_MUX".Mux.Scada[#for_mux].oldSD.Tiempos_SetPointTiempoDes := "DB2005_SD".SD[#t_Index].Tiempos_SetPointTiempoDes;
                                    
                                ELSIF #t_CambioDesdeMux THEN
                                    
                                    //  Al detectar un cambio desde el MUX, cargamos sus valores al dispositivo
                                    "DB2005_SD".SD[#t_Index].Estado_AutoMan := "DB2805_SD_MUX".Mux.Scada[#for_mux].SD.Estado_AutoMan;
                                    "DB2005_SD".SD[#t_Index].Orden_ActivarManual := "DB2805_SD_MUX".Mux.Scada[#for_mux].SD.Orden_ActivarManual;
                                    
                                    "DB2005_SD".SD[#t_Index].Config_DireccionSalidaBit := "DB2805_SD_MUX".Mux.Scada[#for_mux].SD.Config_DireccionSalidaBit;
                                    "DB2005_SD".SD[#t_Index].Config_DireccionSalidaByte := "DB2805_SD_MUX".Mux.Scada[#for_mux].SD.Config_DireccionSalidaByte;
                                    "DB2005_SD".SD[#t_Index].Config_Habilitar := "DB2805_SD_MUX".Mux.Scada[#for_mux].SD.Config_Habilitar;
                                    "DB2005_SD".SD[#t_Index].Config_HabilitarInvertir := "DB2805_SD_MUX".Mux.Scada[#for_mux].SD.Config_HabilitarInvertir;
                                    "DB2005_SD".SD[#t_Index].Config_HabilitarRetardoAct := "DB2805_SD_MUX".Mux.Scada[#for_mux].SD.Config_HabilitarRetardoAct;
                                    "DB2005_SD".SD[#t_Index].Config_HabilitarRetardoDes := "DB2805_SD_MUX".Mux.Scada[#for_mux].SD.Config_HabilitarRetardoDes;
                                    "DB2005_SD".SD[#t_Index].Config_TipoAcceso := "DB2805_SD_MUX".Mux.Scada[#for_mux].SD.Config_TipoAcceso;
                                    "DB2005_SD".SD[#t_Index].Tiempos_SetPointTiempoAct := "DB2805_SD_MUX".Mux.Scada[#for_mux].SD.Tiempos_SetPointTiempoAct;
                                    "DB2005_SD".SD[#t_Index].Tiempos_SetPointTiempoDes := "DB2805_SD_MUX".Mux.Scada[#for_mux].SD.Tiempos_SetPointTiempoDes;
                                    
                                    //  Actualizamos el estado original para configuraciones
                                    "DB2805_SD_MUX".Mux.Scada[#for_mux].oldSD.Config_DireccionSalidaBit := "DB2805_SD_MUX".Mux.Scada[#for_mux].SD.Config_DireccionSalidaBit;
                                    "DB2805_SD_MUX".Mux.Scada[#for_mux].oldSD.Config_DireccionSalidaByte := "DB2805_SD_MUX".Mux.Scada[#for_mux].SD.Config_DireccionSalidaByte;
                                    "DB2805_SD_MUX".Mux.Scada[#for_mux].oldSD.Config_Habilitar := "DB2805_SD_MUX".Mux.Scada[#for_mux].SD.Config_Habilitar;
                                    "DB2805_SD_MUX".Mux.Scada[#for_mux].oldSD.Config_HabilitarInvertir := "DB2805_SD_MUX".Mux.Scada[#for_mux].SD.Config_HabilitarInvertir;
                                    "DB2805_SD_MUX".Mux.Scada[#for_mux].oldSD.Config_HabilitarRetardoAct := "DB2805_SD_MUX".Mux.Scada[#for_mux].SD.Config_HabilitarRetardoAct;
                                    "DB2805_SD_MUX".Mux.Scada[#for_mux].oldSD.Config_HabilitarRetardoDes := "DB2805_SD_MUX".Mux.Scada[#for_mux].SD.Config_HabilitarRetardoDes;
                                    "DB2805_SD_MUX".Mux.Scada[#for_mux].oldSD.Config_TipoAcceso := "DB2805_SD_MUX".Mux.Scada[#for_mux].SD.Config_TipoAcceso;
                                    "DB2805_SD_MUX".Mux.Scada[#for_mux].oldSD.Tiempos_SetPointTiempoAct := "DB2805_SD_MUX".Mux.Scada[#for_mux].SD.Tiempos_SetPointTiempoAct;
                                    "DB2805_SD_MUX".Mux.Scada[#for_mux].oldSD.Tiempos_SetPointTiempoDes := "DB2805_SD_MUX".Mux.Scada[#for_mux].SD.Tiempos_SetPointTiempoDes;
                                    
                                END_IF;
                                
                            END_REGION TRASPASO_DATOS
                            
                            
                        END_REGION DATOS_ESCRITURA 
                        
                    ELSE
                        
                        //  ===========================================================================================================
                        //  En caso de que el indice sea 0, movemos el valor de la SD[0] que no se usa para escribir el index.
                        "DB2805_SD_MUX".Mux.Scada[#for_mux].SD := "DB2005_SD".SD[0];
                        "DB2805_SD_MUX".Mux.Scada[#for_mux].oldSD := "DB2005_SD".SD[0];
                        
                        //  Actualizacion de estado anterior
                        "DB2805_SD_MUX".Mux.Scada[#for_mux].oldIndex := 0;
                        
                    END_IF;
                    
                ELSE
                    
                    "DB2805_SD_MUX".Mux.Scada[#for_mux].Index :=
                    "DB2805_SD_MUX".Mux.Scada[#for_mux].oldIndex := 0;
                    
                END_IF;
                
            END_FOR;
            
        END_REGION MULTIPLEXADO
        
    END_NETWORK
END_FUNCTION
