{
    S7_Author := "ABH";
    S7_BlockComment := "MLC_4CZ";
    S7_BlockNumber := "2825";
    S7_BlockTitle := "MLC_3Yw";
    S7_EditorMode := "SCL";
    S7_Family := "ZeusControl";
    S7_Optimized := "TRUE";
    S7_Version := "1.0"
}
FUNCTION "FC2825_ZC_TOT_MUX" : Void
    VAR_INPUT
        { S7_MLC := "MLC_4HG" }
        Arranque : Bool;
    END_VAR
    VAR_TEMP
        for_mux : Int;
        t_Index : Int;
        t_oldIndex : Int;
        t_N_MAX : Int;
        t_CambioDesdeHMI : Bool;
        t_CambioDesdeMux : Bool;
    END_VAR

    { S7_Language := "SCL" }
    NETWORK
        REGION DESCRIPCION
        (*
        ###### (C)Copyright ZeusControl 2026 - 2026
        
        ---
        ### Información del Sistema
        | Hardware Compatible | Entorno de Ingeniería |
        |---------------------|-----------------------|
        | PLC serie 1200/1500 | TIA Portal 18         |
        
        ---
        > **Restricciones:** Ninguna.
        
        - - -
        ### Descripción Funcional
        El bloque implementa la gestión de multiplexado estático para el dispositivo totalizador, exponiendo la matriz de equipos de la planta a los sistemas de supervisión SCADA Clásicos (WinCC Professional) sin necesidad de acceso indexado nativo.
        
        Funcionalidades principales de la arquitectura:
        - En el primer arranque del PLC (`#Arranque`), inicializa a `0` los índices (`Index` y `oldIndex`) de todos los canales de multiplexado.
        - Validación de los límites del índice de cada multiplexado frente a la constante `N_MAX_DISP_TOT`.
        - Detección de cambio de índice (`Index <> oldIndex`) para cargar la estructura completa del equipo seleccionado (`DB2025_TOT.TOT[X]`) en la interfaz del multiplexor.
        - Transferencia continua de datos de Solo Lectura (estados, valores actuales, alarmas) desde el PLC hacia el SCADA.
        - Transferencia bidireccional segura de datos de Escritura (consignas, configuraciones y modos) evaluando máscaras de cambios (`CambioDesdeHMI` vs `CambioDesdeMux`) para evitar sobrescrituras accidentales.
        - Gestión de comandos (Resets, pulsadores) con auto-reseteo para evitar el efecto rebote.
        - Caso especial de índice `0`: carga la estructura `TOT[0]` (reservada y vacía) para limpiar la pantalla del SCADA.
        
        > ** Restricciones: ** Exclusivo para SCADAs sin soporte de indexación directa.
        
        - - -
        ### Dependencias Requeridas
        | Tipo | Elementos |
        |------|-----------|
        | FC   | - |
        | FB   | - |
        | DB   | `DB2025_TOT` |
        | UDT  | `ZC_DISP_TOT`, `ZC_DISP_MUX_TOT` | 
        ---
        ### Historial de Cambios
        | Versión  | Fecha      | Técnico | Cambios |
        |----------|------------|---------|---------|
        | 01.00.00 | 10.07.2026 | (ABH)   | Primera versión extraído a FC independiente. Refactorizacion de multiplexado para su uso solo en WinCC Professional.|
        *)
        END_REGION DESCRIPCION
        
        
        REGION COMPROBACION_N_MAX
            
            //  Si no hay Scada declarados, salimos del bloque inmediatamente
            IF "N_MAX_SCADA" <= 0 THEN
                RETURN;
            END_IF;
            
            //  Traspaso de N_MAX a variable temporal para evitar fallos de compilacion
            #t_N_MAX := "N_MAX_SCADA";
            
        END_REGION COMPROBACION_N_MAX
        
        
        REGION MULTIPLEXADO
            
            //  ===========================================================================================================
            //  Al arranque del PLC, ponemos a 0 todos los indices de los multiplexados
            IF #Arranque THEN
                FOR #for_mux := 1 TO #t_N_MAX DO
                    "DB2825_TOT_MUX".Mux.Scada[#for_mux].Index :=
                    "DB2825_TOT_MUX".Mux.Scada[#for_mux].oldIndex := 0;
                END_FOR;
            END_IF;
            
            //  Gestion de multiplexado
            FOR #for_mux := 1 TO #t_N_MAX DO
                
                //  Antes de iniciar la logica del multiplexado, revisamos los limites
                REGION LIMITES
                    
                    //  Limites
                    IF "DB2825_TOT_MUX".Mux.Scada[#for_mux].Index < 0 THEN
                        "DB2825_TOT_MUX".Mux.Scada[#for_mux].Index := 0;
                    END_IF;
                    IF "DB2825_TOT_MUX".Mux.Scada[#for_mux].Index > "N_MAX_DISP_TOT" THEN
                        "DB2825_TOT_MUX".Mux.Scada[#for_mux].Index := "N_MAX_DISP_TOT";
                    END_IF;
                    
                END_REGION LIMITES
                
                
                REGION INDICES
                    
                    //  Pasamos el indice a variable temporal para evisar cambios no deseados
                    #t_Index := "DB2825_TOT_MUX".Mux.Scada[#for_mux].Index;
                    #t_oldIndex := "DB2825_TOT_MUX".Mux.Scada[#for_mux].oldIndex;
                    
                END_REGION INDICES
                
                
                IF "DB2825_TOT_MUX".Mux.Scada[#for_mux].Habilitar THEN
                    
                    //  Gestionamos solo los tipos 
                    IF #t_Index > 0 THEN
                        
                        REGION CARGA_INICIAL
                            
                            //  Al detectar un cambio en el indice del dispositivo, cargamos los valores del dispositivo que tenga el indice.
                            IF #t_Index <> #t_oldIndex THEN
                                
                                //  Traspaso de dispositivos al multiplexado
                                "DB2825_TOT_MUX".Mux.Scada[#for_mux].TOT := "DB2025_TOT".TOT[#t_Index];
                                "DB2825_TOT_MUX".Mux.Scada[#for_mux].oldTOT := "DB2025_TOT".TOT[#t_Index];
                                
                                //  ===========================================================================================================
                                //  Valor anterior del indice
                                "DB2825_TOT_MUX".Mux.Scada[#for_mux].oldIndex := #t_Index;
                                
                            END_IF;
                            
                        END_REGION CARGA_INICIAL
                        
                        
                        REGION DATOS_LECTURA
                            
                            //  ===========================================================================================================
                            //  Movimiento de datos gestionados en FC
                            "DB2825_TOT_MUX".Mux.Scada[#for_mux].TOT.Hmi_Estado := "DB2025_TOT".TOT[#t_Index].Hmi_Estado;
                            "DB2825_TOT_MUX".Mux.Scada[#for_mux].TOT.Estado_Pulso := "DB2025_TOT".TOT[#t_Index].Estado_Pulso;
                            "DB2825_TOT_MUX".Mux.Scada[#for_mux].TOT.Estado_Valor := "DB2025_TOT".TOT[#t_Index].Estado_Valor;
                            "DB2825_TOT_MUX".Mux.Scada[#for_mux].TOT.Estado_Total := "DB2025_TOT".TOT[#t_Index].Estado_Total;
                            "DB2825_TOT_MUX".Mux.Scada[#for_mux].TOT.Estado_Parcial := "DB2025_TOT".TOT[#t_Index].Estado_Parcial;
                            "DB2825_TOT_MUX".Mux.Scada[#for_mux].TOT.Estado_Proceso := "DB2025_TOT".TOT[#t_Index].Estado_Proceso;
                            "DB2825_TOT_MUX".Mux.Scada[#for_mux].TOT.Estado_Usuario := "DB2025_TOT".TOT[#t_Index].Estado_Proceso;
                            "DB2825_TOT_MUX".Mux.Scada[#for_mux].TOT.Estado_DesbordeTotal := "DB2025_TOT".TOT[#t_Index].Estado_DesbordeTotal;
                            "DB2825_TOT_MUX".Mux.Scada[#for_mux].TOT.Estado_DesbordeParcial := "DB2025_TOT".TOT[#t_Index].Estado_DesbordeParcial;
                            "DB2825_TOT_MUX".Mux.Scada[#for_mux].TOT.Estado_DesbordeUsuario := "DB2025_TOT".TOT[#t_Index].Estado_DesbordeUsuario;
                            "DB2825_TOT_MUX".Mux.Scada[#for_mux].TOT.Orden_Activar := "DB2025_TOT".TOT[#t_Index].Orden_Activar;
                            "DB2825_TOT_MUX".Mux.Scada[#for_mux].TOT.Orden_ResetProceso := "DB2025_TOT".TOT[#t_Index].Orden_ResetProceso;
                            "DB2825_TOT_MUX".Mux.Scada[#for_mux].TOT.Aux_oldActivado := "DB2025_TOT".TOT[#t_Index].Aux_oldActivado;
                            "DB2825_TOT_MUX".Mux.Scada[#for_mux].TOT.Aux_oldAlarma := "DB2025_TOT".TOT[#t_Index].Aux_oldAlarma;
                            "DB2825_TOT_MUX".Mux.Scada[#for_mux].TOT.Aux_AcuTiempo := "DB2025_TOT".TOT[#t_Index].Aux_AcuTiempo;
                            "DB2825_TOT_MUX".Mux.Scada[#for_mux].TOT.Aux_TotalizadorMem := "DB2025_TOT".TOT[#t_Index].Aux_TotalizadorMem;
                            
                            
                        END_REGION DATOS_LECTURA
                        
                        
                        REGION DATOS_ESCRITURA
                            
                            REGION GESTION_CAMBIOS_DINAMICOS
                                
                                //  ===========================================================================================================
                                //  Orden activar usuario
                                IF "DB2025_TOT".TOT[#t_Index].Orden_Usuario <> "DB2825_TOT_MUX".Mux.Scada[#for_mux].oldTOT.Orden_Usuario THEN
                                    //  Cambio desde HMI
                                    "DB2825_TOT_MUX".Mux.Scada[#for_mux].TOT.Orden_Usuario := "DB2025_TOT".TOT[#t_Index].Orden_Usuario;
                                    "DB2825_TOT_MUX".Mux.Scada[#for_mux].oldTOT.Orden_Usuario := "DB2025_TOT".TOT[#t_Index].Orden_Usuario;
                                ELSIF "DB2825_TOT_MUX".Mux.Scada[#for_mux].TOT.Orden_Usuario <> "DB2825_TOT_MUX".Mux.Scada[#for_mux].oldTOT.Orden_Usuario THEN
                                    //  Cambio desde Multiplexado
                                    "DB2025_TOT".TOT[#t_Index].Orden_Usuario := "DB2825_TOT_MUX".Mux.Scada[#for_mux].TOT.Orden_Usuario;
                                    "DB2825_TOT_MUX".Mux.Scada[#for_mux].oldTOT.Orden_Usuario := "DB2825_TOT_MUX".Mux.Scada[#for_mux].TOT.Orden_Usuario;
                                END_IF;
                                
                                //  ===========================================================================================================
                                //  Reset parcial
                                IF "DB2025_TOT".TOT[#t_Index].Orden_ResetParcial <> "DB2825_TOT_MUX".Mux.Scada[#for_mux].oldTOT.Orden_ResetParcial THEN
                                    //  Cambio desde HMI
                                    "DB2825_TOT_MUX".Mux.Scada[#for_mux].TOT.Orden_ResetParcial := "DB2025_TOT".TOT[#t_Index].Orden_ResetParcial;
                                    "DB2825_TOT_MUX".Mux.Scada[#for_mux].oldTOT.Orden_ResetParcial := "DB2025_TOT".TOT[#t_Index].Orden_ResetParcial;
                                ELSIF "DB2825_TOT_MUX".Mux.Scada[#for_mux].TOT.Orden_ResetParcial <> "DB2825_TOT_MUX".Mux.Scada[#for_mux].oldTOT.Orden_ResetParcial THEN
                                    //  Cambio desde Multiplexado
                                    "DB2025_TOT".TOT[#t_Index].Orden_ResetParcial := "DB2825_TOT_MUX".Mux.Scada[#for_mux].TOT.Orden_ResetParcial;
                                    "DB2825_TOT_MUX".Mux.Scada[#for_mux].oldTOT.Orden_ResetParcial := "DB2825_TOT_MUX".Mux.Scada[#for_mux].TOT.Orden_ResetParcial;
                                    "DB2825_TOT_MUX".Mux.Scada[#for_mux].TOT.Orden_ResetParcial := FALSE;
                                END_IF;
                                
                                //  ===========================================================================================================
                                //  Reset total
                                IF "DB2025_TOT".TOT[#t_Index].Orden_ResetTotal <> "DB2825_TOT_MUX".Mux.Scada[#for_mux].oldTOT.Orden_ResetTotal THEN
                                    //  Cambio desde HMI
                                    "DB2825_TOT_MUX".Mux.Scada[#for_mux].TOT.Orden_ResetTotal := "DB2025_TOT".TOT[#t_Index].Orden_ResetTotal;
                                    "DB2825_TOT_MUX".Mux.Scada[#for_mux].oldTOT.Orden_ResetTotal := "DB2025_TOT".TOT[#t_Index].Orden_ResetTotal;
                                ELSIF "DB2825_TOT_MUX".Mux.Scada[#for_mux].TOT.Orden_ResetTotal <> "DB2825_TOT_MUX".Mux.Scada[#for_mux].oldTOT.Orden_ResetTotal THEN
                                    //  Cambio desde Multiplexado
                                    "DB2025_TOT".TOT[#t_Index].Orden_ResetTotal := "DB2825_TOT_MUX".Mux.Scada[#for_mux].TOT.Orden_ResetTotal;
                                    "DB2825_TOT_MUX".Mux.Scada[#for_mux].oldTOT.Orden_ResetTotal := "DB2825_TOT_MUX".Mux.Scada[#for_mux].TOT.Orden_ResetTotal;
                                    "DB2825_TOT_MUX".Mux.Scada[#for_mux].TOT.Orden_ResetTotal := FALSE;
                                END_IF;
                                
                                //  ===========================================================================================================
                                //  Reset usuario
                                IF "DB2025_TOT".TOT[#t_Index].Orden_ResetUsuario <> "DB2825_TOT_MUX".Mux.Scada[#for_mux].oldTOT.Orden_ResetUsuario THEN
                                    //  Cambio desde HMI
                                    "DB2825_TOT_MUX".Mux.Scada[#for_mux].TOT.Orden_ResetUsuario := "DB2025_TOT".TOT[#t_Index].Orden_ResetUsuario;
                                    "DB2825_TOT_MUX".Mux.Scada[#for_mux].oldTOT.Orden_ResetUsuario := "DB2025_TOT".TOT[#t_Index].Orden_ResetUsuario;
                                ELSIF "DB2825_TOT_MUX".Mux.Scada[#for_mux].TOT.Orden_ResetUsuario <> "DB2825_TOT_MUX".Mux.Scada[#for_mux].oldTOT.Orden_ResetUsuario THEN
                                    //  Cambio desde Multiplexado
                                    "DB2025_TOT".TOT[#t_Index].Orden_ResetUsuario := "DB2825_TOT_MUX".Mux.Scada[#for_mux].TOT.Orden_ResetUsuario;
                                    "DB2825_TOT_MUX".Mux.Scada[#for_mux].oldTOT.Orden_ResetUsuario := "DB2825_TOT_MUX".Mux.Scada[#for_mux].TOT.Orden_ResetUsuario;
                                    "DB2825_TOT_MUX".Mux.Scada[#for_mux].TOT.Orden_ResetUsuario := FALSE;
                                END_IF;
                                
                            END_REGION GESTION_CAMBIOS_DINAMICOS
                            
                            
                            REGION GESTION_CAMBIOS_CONFIG
                                
                                //  Marca auxiliar para indicar que el cambio es desde HMI
                                //  Comparamos el dispositivo original con el dispositivo real, para detectar cambios desde PLC o desde HMI
                                #t_CambioDesdeHMI :=
                                ("DB2825_TOT_MUX".Mux.Scada[#for_mux].oldTOT.Config_Habilitar <> "DB2025_TOT".TOT[#t_Index].Config_Habilitar)
                                OR ("DB2825_TOT_MUX".Mux.Scada[#for_mux].oldTOT.Config_Tipo <> "DB2025_TOT".TOT[#t_Index].Config_Tipo)
                                OR ("DB2825_TOT_MUX".Mux.Scada[#for_mux].oldTOT.Config_IncrDecr <> "DB2025_TOT".TOT[#t_Index].Config_IncrDecr)
                                OR ("DB2825_TOT_MUX".Mux.Scada[#for_mux].oldTOT.Config_DireccionEntradaByte <> "DB2025_TOT".TOT[#t_Index].Config_DireccionEntradaByte)
                                OR ("DB2825_TOT_MUX".Mux.Scada[#for_mux].oldTOT.Config_DireccionEntradaBit <> "DB2025_TOT".TOT[#t_Index].Config_DireccionEntradaBit)
                                OR ("DB2825_TOT_MUX".Mux.Scada[#for_mux].oldTOT.Config_LitroXPulso <> "DB2025_TOT".TOT[#t_Index].Config_LitroXPulso);
                                
                                //  Marca auxiliar para indicar que el cambio es desde MUX SCADA
                                //  Comparamos el dispositivo original con el multiplexado, para detectar cambios desde multiplexado
                                #t_CambioDesdeMux :=
                                ("DB2825_TOT_MUX".Mux.Scada[#for_mux].TOT.Config_Habilitar <> "DB2825_TOT_MUX".Mux.Scada[#for_mux].oldTOT.Config_Habilitar)
                                OR ("DB2825_TOT_MUX".Mux.Scada[#for_mux].TOT.Config_Tipo <> "DB2825_TOT_MUX".Mux.Scada[#for_mux].oldTOT.Config_Tipo)
                                OR ("DB2825_TOT_MUX".Mux.Scada[#for_mux].TOT.Config_IncrDecr <> "DB2825_TOT_MUX".Mux.Scada[#for_mux].oldTOT.Config_IncrDecr)
                                OR ("DB2825_TOT_MUX".Mux.Scada[#for_mux].TOT.Config_DireccionEntradaByte <> "DB2825_TOT_MUX".Mux.Scada[#for_mux].oldTOT.Config_DireccionEntradaByte)
                                OR ("DB2825_TOT_MUX".Mux.Scada[#for_mux].TOT.Config_DireccionEntradaBit <> "DB2825_TOT_MUX".Mux.Scada[#for_mux].oldTOT.Config_DireccionEntradaBit)
                                OR ("DB2825_TOT_MUX".Mux.Scada[#for_mux].TOT.Config_LitroXPulso <> "DB2825_TOT_MUX".Mux.Scada[#for_mux].oldTOT.Config_LitroXPulso);
                                
                            END_REGION GESTION_CAMBIOS_CONFIG
                            
                            
                            REGION TRASPASO_DATOS
                                
                                IF #t_CambioDesdeHMI THEN
                                    
                                    //  Al detectar un cambio desde el HMI, cargamos sus valores de nuevo al multiplexado
                                    "DB2825_TOT_MUX".Mux.Scada[#for_mux].TOT.Config_Habilitar := "DB2025_TOT".TOT[#t_Index].Config_Habilitar;
                                    "DB2825_TOT_MUX".Mux.Scada[#for_mux].TOT.Config_Tipo := "DB2025_TOT".TOT[#t_Index].Config_Tipo;
                                    "DB2825_TOT_MUX".Mux.Scada[#for_mux].TOT.Config_IncrDecr := "DB2025_TOT".TOT[#t_Index].Config_IncrDecr;
                                    "DB2825_TOT_MUX".Mux.Scada[#for_mux].TOT.Config_DireccionEntradaByte := "DB2025_TOT".TOT[#t_Index].Config_DireccionEntradaByte;
                                    "DB2825_TOT_MUX".Mux.Scada[#for_mux].TOT.Config_DireccionEntradaBit := "DB2025_TOT".TOT[#t_Index].Config_DireccionEntradaBit;
                                    "DB2825_TOT_MUX".Mux.Scada[#for_mux].TOT.Config_LitroXPulso := "DB2025_TOT".TOT[#t_Index].Config_LitroXPulso;
                                    
                                    
                                    //  Actualizamos el estado original para configuraciones
                                    "DB2825_TOT_MUX".Mux.Scada[#for_mux].oldTOT.Config_Habilitar := "DB2025_TOT".TOT[#t_Index].Config_Habilitar;
                                    "DB2825_TOT_MUX".Mux.Scada[#for_mux].oldTOT.Config_Tipo := "DB2025_TOT".TOT[#t_Index].Config_Tipo;
                                    "DB2825_TOT_MUX".Mux.Scada[#for_mux].oldTOT.Config_IncrDecr := "DB2025_TOT".TOT[#t_Index].Config_IncrDecr;
                                    "DB2825_TOT_MUX".Mux.Scada[#for_mux].oldTOT.Config_DireccionEntradaByte := "DB2025_TOT".TOT[#t_Index].Config_DireccionEntradaByte;
                                    "DB2825_TOT_MUX".Mux.Scada[#for_mux].oldTOT.Config_DireccionEntradaBit := "DB2025_TOT".TOT[#t_Index].Config_DireccionEntradaBit;
                                    "DB2825_TOT_MUX".Mux.Scada[#for_mux].oldTOT.Config_LitroXPulso := "DB2025_TOT".TOT[#t_Index].Config_LitroXPulso;
                                    
                                ELSIF #t_CambioDesdeMux THEN
                                    
                                    //  Al detectar un cambio desde el MUX, cargamos sus valores al dispositivo
                                    "DB2025_TOT".TOT[#t_Index].Config_Habilitar := "DB2825_TOT_MUX".Mux.Scada[#for_mux].TOT.Config_Habilitar;
                                    "DB2025_TOT".TOT[#t_Index].Config_Tipo := "DB2825_TOT_MUX".Mux.Scada[#for_mux].TOT.Config_Tipo;
                                    "DB2025_TOT".TOT[#t_Index].Config_IncrDecr := "DB2825_TOT_MUX".Mux.Scada[#for_mux].TOT.Config_IncrDecr;
                                    "DB2025_TOT".TOT[#t_Index].Config_DireccionEntradaByte := "DB2825_TOT_MUX".Mux.Scada[#for_mux].TOT.Config_DireccionEntradaByte;
                                    "DB2025_TOT".TOT[#t_Index].Config_DireccionEntradaBit := "DB2825_TOT_MUX".Mux.Scada[#for_mux].TOT.Config_DireccionEntradaBit;
                                    "DB2025_TOT".TOT[#t_Index].Config_LitroXPulso := "DB2825_TOT_MUX".Mux.Scada[#for_mux].TOT.Config_LitroXPulso;
                                    
                                    //  Actualizamos el estado original para configuraciones
                                    "DB2825_TOT_MUX".Mux.Scada[#for_mux].oldTOT.Config_Habilitar := "DB2825_TOT_MUX".Mux.Scada[#for_mux].TOT.Config_Habilitar;
                                    "DB2825_TOT_MUX".Mux.Scada[#for_mux].oldTOT.Config_Tipo := "DB2825_TOT_MUX".Mux.Scada[#for_mux].TOT.Config_Tipo;
                                    "DB2825_TOT_MUX".Mux.Scada[#for_mux].oldTOT.Config_IncrDecr := "DB2825_TOT_MUX".Mux.Scada[#for_mux].TOT.Config_IncrDecr;
                                    "DB2825_TOT_MUX".Mux.Scada[#for_mux].oldTOT.Config_DireccionEntradaByte := "DB2825_TOT_MUX".Mux.Scada[#for_mux].TOT.Config_DireccionEntradaByte;
                                    "DB2825_TOT_MUX".Mux.Scada[#for_mux].oldTOT.Config_DireccionEntradaBit := "DB2825_TOT_MUX".Mux.Scada[#for_mux].TOT.Config_DireccionEntradaBit;
                                    "DB2825_TOT_MUX".Mux.Scada[#for_mux].oldTOT.Config_LitroXPulso := "DB2825_TOT_MUX".Mux.Scada[#for_mux].TOT.Config_LitroXPulso;
                                    
                                END_IF;
                                
                            END_REGION TRASPASO_DATOS                    
                            
                        END_REGION DATOS_ESCRITURA
                        
                    ELSE
                        
                        //  En caso de que el indice sea 0, movemos el valor de la TOT[0] que no se usa para escribir el index.
                        "DB2825_TOT_MUX".Mux.Scada[#for_mux].TOT := "DB2025_TOT".TOT[0];
                        "DB2825_TOT_MUX".Mux.Scada[#for_mux].oldTOT := "DB2025_TOT".TOT[0];
                        
                        //  Actualizacion de estado anterior
                        "DB2825_TOT_MUX".Mux.Scada[#for_mux].oldIndex := 0;
                        
                    END_IF;
                    
                ELSE
                    
                    //  Multiplexado no habilitado
                    "DB2825_TOT_MUX".Mux.Scada[#for_mux].Index :=
                    "DB2825_TOT_MUX".Mux.Scada[#for_mux].oldIndex := 0;
                    
                END_IF;
                
            END_FOR;
            
        END_REGION MULTIPLEXADO
        
    END_NETWORK
END_FUNCTION
